嵌入式linux学习（四）：存储管理器

学习 S3C2440
  view

简单介绍一下存储管理器的作用和使用，位操作以及2440的启动方式。

一、存储管理器的作用和使用

1、基本概念

存储管理器，负责管理2440的一些外接芯片，比如外接的SDRAM和DM9000等。在配置好存储管理器后，cpu不需要知道芯片信号或者其他一些信息，只需要知道地址便可以通过简单的指令访问外接设备。
比如：cpu需要从0x30000000地址读取4字节的数据，cpu不需要知道外部设备型号，只需要执行两条指令就行。

1
2
mov R1,#0x30000000
ldr R0,[R1]

外部设备的型号，如何访问，这些都是存储管理器的工作。对于具体的片选信号、bank选择信号、列地址、行地址等等与硬件相关的不需要cpu去管，这些工作由存储管理器完成。

2、读SDRAM时，存储管理器配置信息

访问一个芯片，最基本的一些条件（配置信息）：
1）地址线
2）数据线：数据宽度
3）时钟、频率
4）芯片相关特性（比如访问SDRAM，需要行、列地址以及选择bank）
2440有8个bank，可以接8个和内存设备类似的芯片
（补充：SDRAM的内部是一个存储阵列，如同表格一样，将数据“填”进去。先指定行，再指定列，就可以准确找到所需单元格。该单元格被称为存储单元，这个表格就是逻辑bank，SDRAM一般有4个L——bank）

3、配置存储管理器（写REG）

1、REG信息

1）BWSCON （总线宽度，等待控制寄存器） 设置bank，选择位宽，是否等待
2）BANKCON0~BANKCON7 （bank x 控制寄存器） 设置如何访问bank
（其中bank6和bank7可以接SDRAM。其他bank可以接一些“ram-like”类型芯片，访问方式和SRAM相同，不需要设置行、列地址以及bank和刷新，直接通过地址操作即可）
3）REFLASH （SDRAM刷新控制寄存器） 设置如何刷新
4）BANKSIZE （自由设置bank大小寄存器） 设置bank的大小
（每个bank可以外接128M设备，BANKSIZE可以自由组合两个bank的大小）
eg：

BANK设置

2、代码

head.S
@ File：head.S
@ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
.equ        MEM_CTL_BASE,       0x48000000
.equ        SDRAM_BASE,         0x30000000

.text
.global _start
_start:
    bl  disable_watch_dog               @ 关闭WATCHDOG，否则CPU会不断重启
    bl  memsetup                        @ 设置存储控制器
    bl  copy_steppingstone_to_sdram     @ 复制代码到SDRAM中
    ldr pc, =on_sdram                   @ 跳到SDRAM中继续执行
on_sdram:
    ldr sp, =0x34000000                 @ 设置堆栈
    bl  main
halt_loop:
    b   halt_loop

disable_watch_dog:
    @ 往WATCHDOG寄存器写0即可
    mov r1,     #0x53000000
    mov r2,     #0x0
    str r2,     [r1]
    mov pc,     lr      @ 返回

copy_steppingstone_to_sdram:
    @ 将Steppingstone的4K数据全部复制到SDRAM中去
    @ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000
    
    mov r1, #0
    ldr r2, =SDRAM_BASE
    mov r3, #4*1024
1:  
    ldr r4, [r1],#4     @ 从Steppingstone读取4字节的数据，并让源地址加4
    str r4, [r2],#4     @ 将此4字节的数据复制到SDRAM中，并让目地地址加4
    cmp r1, r3          @ 判断是否完成：源地址等于Steppingstone的未地址？
    bne 1b              @ 若没有复制完，继续
    mov pc,     lr      @ 返回

memsetup:
    @ 设置存储控制器以便使用SDRAM等外设

    mov r1,     #MEM_CTL_BASE       @ 存储控制器的13个寄存器的开始地址
    adrl    r2, mem_cfg_val         @ 这13个值的起始存储地址
    add r3,     r1, #52             @ 13*4 = 54
1:  
    ldr r4,     [r2], #4            @ 读取设置值，并让r2加4
    str r4,     [r1], #4            @ 将此值写入寄存器，并让r1加4
    cmp r1,     r3                  @ 判断是否设置完所有13个寄存器
    bne 1b                          @ 若没有写成，继续
    mov pc,     lr                  @ 返回

.align 4
mem_cfg_val:
    @ 存储控制器13个寄存器的设置值  
    .long   0x22011110      @ BWSCON
    .long   0x00000700      @ BANKCON0
    .long   0x00000700      @ BANKCON1
    .long   0x00000700      @ BANKCON2
    .long   0x00000700      @ BANKCON3  
    .long   0x00000700      @ BANKCON4
    .long   0x00000700      @ BANKCON5
    .long   0x00018005      @ BANKCON6
    .long   0x00018005      @ BANKCON7
    .long   0x008C07A3      @ REFRESH
    .long   0x000000B1      @ BANKSIZE
    .long   0x00000030      @ MRSRB6
    .long   0x00000030      @ MRSRB7

Makefile

1
2
3
4
5
6
7
8
sdram.bin : head.S  leds.c
    arm-linux-gcc  -c -o head.o head.S
    arm-linux-gcc -c -o leds.o leds.c
    arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf
    arm-linux-objcopy -O binary -S sdram_elf sdram.bin
    arm-linux-objdump -D -m arm  sdram_elf > sdram.dis
clean:
    rm -f   sdram.dis sdram.bin sdram_elf *.o

链接地址0x30000000，运行时程序“应该”位于0x30000000地址处。
head.S一开始是在NANDFLASH上，把head.S从片内SRAM拷到应该执行的地方0x30000000（Makefile中指定）

二、2440启动方式

1、NOR启动

CPU访问的0地址指向NOR FLASH，也就是BANK0，然后CPU从NOR FLASH的0地址读取指令执行。
（0地址指向NOR，NOR接在BANK0）

2、NAND启动

（如果开发板同时有接有NORFLASH和NANDFLASH，设置为NAND启动，那么BANK0无法访问，NOR失效）CPU访问的0地址指向片内SRAM（steppingstone），开发板上电时，会自动把NANDFLASH的前4k内容完全拷贝到片内SRAM里面，然后从0地址运行。MINI2440没有外接NOR，因此只有NAND启动。

3、开发板启动过程

1)上电，NAND前4k拷贝到SRAM，cpu从0地址开始执行
2）关看门狗，初始化存储管理器
3）把SRAM中的代码拷贝到SDRAM，然后到SDRAM中继续执行
（如果代码量很大，那么一般情况下，首先NAND前4k拷到SRAM，然后CPU执行前4k命令时，再把NANDFLASH里面4k之后的代码全部拷贝到SDRAM里，继续执行）
补充：在调用C语言之前要先设置栈

1
2
ldr sp, =0x34000000   
bl  main

共有64MSDRAM，该地址是SDRAM的最顶端。
具体流程：

从NAND FLASH启动

1、从NAND FLASH启动

初始化存储管理器

2、初始化存储管理器

复制代码到SDRAM

3、复制代码到SDRAM

调到SDRAM执行

4、调到SDRAM执行